ブログの説明

学校に通わないで学んだことを記しています。間違っているところが何かありましたらご指摘下さると幸いです。コメントに対する返信が遅れる可能性があります。その場合は申し訳ありません。

このブログではサイドバーに広告を表示しています。このブログ内の投稿記事を検索するには右上の拡大鏡のアイコンを、アーカイブやラベル付けから投稿記事を閲覧するには左上の三重線のアイコンをクリックして下さい。

数式の表示にはMathJaxを利用させていただいています。数式の表示のためにJavaScriptが有効である必要があります。そうでない場合、訳の分からないLatexのコードが表示されます。幾何学図形やチャートの表示にはHTML5 CanvasやGoogle Chartを使用しています。その表示のためにもJavaScriptが有効である必要があります。

LibreOffice Calcでダイアログ上のテキストフィールドからセルへの転記

先回は、LibreOffice Calcのスプレッドシート上に置いたプッシュ・ボタンを押すとダイアログ（フォーム）が開き、そのダイアログ上のコマンド・ボタンを押すとそのダイアログが閉じるマクロをLibreOffice Basicによって作った。

今回は、このダイアログを用いてスプレッドシート上のセルに文字列を入力・転記するコードを書くのが目的。その手順を以下に書き留める。

ここで前提とするLibreOfficeのバージョン
LibreOffice 6.1 Calc
マクロ作成に使用する言語
LibreOffice Basic (Apache OpenOffice Basic)
スプレッドシート・ドキュメントの前提条件
Sheet1という名のシートを1つだけ用意

実装したい機能

今回実現したい機能はおおよそ次のとおり。

  1. LibreOffice Calcのスプレッドシート上に設けたプッシュ・ボタンを押すとダイアログが表示される。
  2. そのダイアログが表示される際、スプレッドシート上のA5というセルに入力されている文字列が、ダイアログ上にあるテキスト・フィールドにも反映される。
  3. ダイアログのテキスト・フィールドに全角または半角の文字列を入力して特定のコマンド・ボタンを押すと、その文字列が10文字以内（11文字未満）であるかどうかを検証し、10文字以内であればその文字列をスプレッドシート上のA5というセルに転記する。
  4. テキスト・フィールドに入力された文字列が11文字以上である場合はその旨を表示して処理を中止する。
  5. ダイアログ上の特定のコマンド・ボタンを押すと、テキスト・フィールドに入力された文字列が削除される。
  6. ダイアログ上の特定のコマンド・ボタンを押すとそのダイアログが非表示になる。

ダイアログとはダイアログ・ボックスのこと。Microsoft Excelではユーザーフォームと呼ばれているものに当たる。

ダイアログ上へ各種コントロールを追加

まずは、前回作成したダイアログ上に各種コントロールを追加する。例えば次のように配置する。

いちばん上にあるのがラベルフィールドと呼ばれるコントロール。上から２番目にあるのがテキスト・フィールドと呼ばれるコントロール。その下にコマンド・ボタンと呼ばれる3つのコントロールが配置されている。

コントロールの属性（プロパティ）の値を変更

ダイアログ上の各種コントロールの属性（プロパティ）の値は次のとおり。ここではそのデフォルトの値を変更した属性のみを示した。

ダイアログ自身
属性名 値
名前 Dialog1
ラベルフィールド
属性名 値
名前 Label1
タイトル 文字列を全角10文字以内で入力してください。
テキスト・フィールド
属性名 値
名前 TextField1
最大文字数 10

最大文字数の値は半角文字にしか適用されないようだ。全角文字だとテキスト・フィールドに何文字でも入力することができてしまう。そのため、マクロを使って10文字未満でないと受け付けないようにコーディングすることにした。

安全なマクロを作成するためには、受け入れるデータができるだけ予想外のものにならないように予め限定することが大事。

コマンド・ボタン1
属性 値
名前 CommandButton_closeDialog
タイトル 閉じる
コマンド・ボタン2
属性 値
名前 CommandButton_postText
タイトル セルへの転記
コマンド・ボタン3
属性 値
名前 CommandButton_clearText
タイトル クリア

スプレッドシート上のプッシュ・ボタンの属性値は次のとおり。

プッシュ・ボタン
属性 値
タイトル ダイアログ表示

名前属性の値は任意でよいけれども、その一部はマクロのコード内容と関連してくるので、今回ここで示すコードを実際に利用する場合には、このとおりの名前でなければコードがうまく機能しない可能性がある。要注意。タイトルは自由。

LibreOffice Basicによるマクロのコーディング

完成されたコードは次のとおり。

REM  *****  BASIC  *****
'ダイアログ上のテキストフィールドに入力された文字列を
'スプレッドシート上の特定のセルに転記する簡単なコード

'変数を明示的に宣言してから使う規則を適用
Option Explicit

'パブリックドメインで各種変数を宣言
'ダイアログオブジェクト用
Dim oDialog As Object
'テキストフィールドオブジェクト用
Dim oTextField As Object
'ドキュメントオブジェクト用
Dim oDoc As Object
'スプレッドシートオブジェクト用
Dim oSheet As Object
'セルオブジェクト用
Dim oCell As Object
'文字列型変数
Dim sText As String

'ダイアログ表示用サブルーチン
Sub openDialog
   'LoadLibraryメソッドでStandardというライブラリを読み込む  
   DialogLibraries.LoadLibrary("Standard")
   'CreateUnoDialog函数でダイアログオブジェクトを生成
   '末尾のDialog1が先ほど作成したダイアログ名
   oDialog = CreateUnoDialog(DialogLibraries.Standard.Dialog1)
  
   '現在のアクティブなドキュメントを取得   
   oDoc = ThisComponent
   '0番目のスプレッドシートを取得
   oSheet = oDoc.getSheets.getByIndex(0)
   'A5というセルを取得
   oCell = oSheet.getCellRangeByName("A5")

   'TextField1というテキストフィールドを取得
   oTextField = oDialog.getControl("TextField1")
   'セルの値を取得して文字列型に変換して代入
   sText = Cstr(oCell.String)
   'テキストフィールドのテキスト属性にそれを設定
   oTextField.setText(sText)

   'Executeメソッドでダイアログを開く
   oDialog.Execute()   
   'Disposeメソッドでリソースを廃棄
   oDialog.Dispose()
End Sub

'ダイアログを閉じるボタン用サブルーチン
Sub closeDialog
   'endExecuteメソッドでダイアログを閉じる
   oDialog.endExecute()
End Sub

'セルへ挿入ボタン用サブルーチン
Sub postText
   'TextField1というテキストフィールドを取得
   oTextField = oDialog.getControl("TextField1")
   'getTextメソッドでテキストフィールドのテキスト属性を取得し
   'Cstr関数で文字列型に変換して代入
   sText = Cstr(oTextField.getText)

   'Len関数で文字列の数を求めて
   'その数が11文字未満ならば
   If Len(sText) < 11 Then
      '現在のアクティブなドキュメントを取得   
      oDoc = ThisComponent
      '0番目のスプレッドシートを取得
      oSheet = oDoc.getSheets.getByIndex(0)
      'A5というセルを取得
      oCell = oSheet.getCellRangeByName("A5")
      'セルに文字列を代入
      oCell.String = sText
   '11文字未満でなければ
   Else
      'メッセージボックスを表示
      MsgBox "10文字以内にしてください。"
   End If
End Sub

'クリアボタン用サブルーチン
Sub clearText
   'テキストフィールドを取得
   oTextField = oDialog.getControl("TextField1")
   'setTextメソッドでテキスト属性を空白に
   oTextField.setText("")
End Sub

Option Explicitによって変数を明示的に宣言してから使う規則を適用した。

サブルーチンの外のパブリック領域にて、各種オブジェクトを格納するオブジェクト型の変数5つと、文字列型の変数1つを宣言。

openDialogというサブルーチンには、ダイアログを表示するためのコード、そしてA5というセルの値をダイアログ上のテキスト・フィールドに表示するためのコードを、それぞれ記述。スプレッドシート上に置かれた「ダイアログ表示」というプッシュ・ボタンのイベントに対してこのサブルーチンを割り当てる。

closeDialogというサブルーチンには、そのダイアログを閉じるためのコードを記述。ダイアログ上に置かれた「閉じる」というコマンド・ボタンのイベントに対してこのサブルーチンを割り当てる。

postTextというサブルーチンには、テキスト・フィールドのテキスト属性から取得した文字列を、その文字数が10文字未満かどうかチェックした上でスプレッドシート上のA5というセルに転記するためのコードを記述。ダイアログ上に置かれた「セルへ転記」というコマンド・ボタンのイベントに対してこのサブルーチンを割り当てる。

clearTextというサブルーチンには、テキスト・フィールドのテキスト属性値を空白にするためのコードを記述。ダイアログ上に置かれた「クリア」というコマンド・ボタンのイベントに対してこのサブルーチンを割り当てる。

各種イベントに対してマクロを割り当てる

各種コントロール（プッシュ・ボタンとコマンド・ボタン）のイベントの一つである「マウスボタンを離した時」に対して各種の処理内容を記したマクロ（サブルーチン）をイベント・ハンドラとして割り当てる。

それらの割り当て表を作ってみた。

「ダイアログ表示」プッシュ・ボタン
イベント マクロ（サブルーチン）
マウスボタンを離した時 Standard.Module1.openDialog (document, Basic)
「閉じる」コマンド・ボタン
イベント マクロ（サブルーチン）
マウスボタンを離した時 Standard.Module1.closeDialog (document, Basic)
「セルへ転記」コマンド・ボタン
イベント マクロ（サブルーチン）
マウスボタンを離した時 Standard.Module1.postText (document, Basic)
「クリア」コマンド・ボタン
イベント マクロ（サブルーチン）
マウスボタンを離した時 Standard.Module1.clearText (document, Basic)

イベントに対してマクロ（サブルーチン）を割り当てる手順は次のとおり。

  1. 目的のコントロールを選択された状態にする。
  2. プロパティウィンドウの中の「イベント」タブを選び、「マウスボタンを離した時」というイベントの右端にあるボタンを押す。
  3. そうすると「アクションの割り当て」ダイアログが開く。そのイベント一覧で「マウスボタンを離した時」が選ばれていることを確認の上、「マクロ」ボタンを押す。
  4. そうすると「マクロセレクター」ダイアログが開く。ライブラリの一覧からModule1を選ぶ。
  5. そうするとマクロ名（サブルーチン名）の一覧が表示されるので、適切なマクロを選ぶ。
  6. そしてOKボタンを押してダイアログを閉じれば割り当ては完了。

各種の作業の後に作業中のスプレッドシートをその都度保存することを忘れずに。

実行結果

今回作ったマクロ（ダイアログを使った入力データの転記）の実行結果は次のようになる。

関連記事

コメント

  1. Bill2021年2月26日 10:29

    「
    セルへの転記」をクリックしたときに最終セルの下に記入されるようにするには

    返信削除
  2. jeorious2022年7月1日 0:26

    それね😅

    返信削除

コメントを投稿

このブログの人気の投稿

LATEXで数式：指数と順列などで使う添数・添字

累乗（べき乗）で使われる指数（べき）など、右上に添えられる数や文字や記号はキャレット記号を用いて次のように表記することができる。添えられる数や文字や記号が複数に及んだり数式になる場合はそれらを{}で囲う必要がある。ちなみに、・は\cdotを、÷は\divを、≠は\neqをそれぞれ用い、分数は\frac{}{}で乗根は\sqrt[]{}で表すことができる。スペースを有効にするには\をスペースの前に付ける。 aのn乗 \( a^n \) a^n \( a^3 = a \cdot a \cdot a \) a^3 = a \cdot a \cdot a \( a^{m+n} \) a^{m+n} 指数法則 \( a^0 = 1 \ (a \neq 0) \) a^0 = 1 \ (a \neq 0) 指数法則 \( a^{\frac{1}{n}} = \sqrt[n]{a} \) a^{\frac{1}{n}} = \sqrt[n]{a} 指数法則 \( a^{\frac{m}{n}} = \sqrt[n]{a^m} \) a^{\frac{m}{n}} = \sqrt[n]{a^m} 指数法則 \( a^{-\frac{m}{n}} = \frac{1}{\sqrt[n]{a^m}} \) a^{-\frac{m}{n}} = \frac{1}{\sqrt[n]{a^m}} 指数法則 \( a^m a^n = a^{m+n} \) a^m a^n = a^{m+n} 指数法則 \( \frac{a^m}{a^n} = \frac{1}{a^{n-m}} \ (m < n) \) \frac{a^m}{a^n} = \frac{1}{a^{n-m}} \ (m < n) 指数法則 \( (a^m)^n = a^{mn} \) (a^m)^n = a^{mn} 指数法則 \( (ab)^n = a^n b^n \) (ab)^n = a^n b^n 指数法則 \( \left(\frac{a}{b}\right)^n = \frac{a^n}{b^n} \) \left(\frac{a}{b}\right)^n = \frac{a^n}{b^n} 指数法則 \( \frac{a^m}{a^n}
続きを読む

10の補数と9の補数と2の補数と1の補数

10進数と10の補数 10進法の四則演算に慣れている人なら算術的な直感で分かるのが10の補数。 算盤 そろばん を使っている人は10の補数と5の補数を出力する函数を会得しているかもしれない。 例えば、2に対して10の補数はいくつかと問われればそれは8だと分かるし、6に対して10の補数はいくつかと問われればそれは4だと分かるし、5に対して10の補数はいくつかと問われれば5だと直感的に分かる。 また、3に対して5の補数はいくつかと問われればそれは2だと分かるし、2に対して5の補数はいくつかと問われれば3だと分かる。 10の補数とは、ある自然数に対してそれにいくつの自然数を加えれば10になるのかという問いに答えたもの。自然数とは、ここでは0, 1, 2, 3, 4, 5, 6, 7, 8, 9のこと。 ある自然数xに対する10の補数yは次のように計算することによって答えることができる。 \[ y = 10 - x \] 10進法の位取り記数法では、桁上がり（位上がり）が起こる数が10であるので、ある数にあといくつ足すと桁上がりが起こるかを理解していることは、その四則演算においてとても重要な暗記事項になっている。 10進法の四則演算に慣れた人の頭の中には次のような函数または対応表があるのかもしれない。 \[ f(x) = 10 - x \] xは引数。「xに対する10の補数」を出力してくれる函数f(x)。 10の補数の対応表 10進数 10の補数 0 10 1 9 2 8 3 7 4 6 5 5 6 4 7 3 8 2 9 1 10 0 補数のこの対応表を見ると、数値を小さい順から並べた昇順と数値を大きい順から並べた降順との写像（マッピング）関係に見える。 10の補数と桁上がり 例えば、\( 6 + 7 = \)を計算するとき、人は6または7の補数を瞬時に思い浮かべ、加える数がそれを上回っている場合に桁上がりが起こると即座に認識するはず。つまり、6に対する10の補数である4を思い浮かべ、その4より大きい7から4を引いた数である3と10を足し合わせて答えを計算するかもしれない。 \[ \begin{align*} 6 + 7 &=
続きを読む

Visual Studio 2019にはC++のためのフォームデザイナーがない件

イメージ
Visual Studio 2019を利用してC++でWindowsフォームアプリを作成しようと「新しいプロジェクトの作成」で「Windowsデスクトップアプリケーション」を選んでみたものの、フォーム・デザイナーが見当たらないことに気が付いた。ユーザー・インターフェイスはソースコードを直接いじれということか。これは厳しい。 C++を諦めてC#でフォームをデザインしろというのが常識的な対処法になるのかもしれないが、それでもC++で作る必要があるという隙間需要を考慮し、今回はこの問題に対処する二通りの対処法をインターネット上で見つけることができたので紹介したいと思う。 Visual Studio Installerでは、「.NETデスクトップ開発」と「C++によるデスクトップ開発」にチェックを入れてインストールしておいたのだけれど、これだけではデフォルトで「ビルドツールC++/CLIサポート」がインストールされないようだ。これを追加インストールする必要がまずあった。その手順は次のとおり。 対処法１ コードを追加する方法 Visual Studio Installerをまず起動した。 「インストール済み」のVisual Studio **** 2019に対して「変更」を選んだ。 「ワークロード」タブで「.NETデスクトップ環境」と「C++によるデスクトップ環境」の両方にチェックが入っていることを確認した。 「個別のコンポーネント」タブを選び、「C++/CLI」として検索した。そうするとビルドツールのC++/CLIサポートの一覧が表示された。 この執筆時点では「v142ビルドツール(14.27)のC++/CLIサポート」がどうやら最新版のように見えたのでこれにチェックを入れた。 そうしておいてからそのダイアログ・ボックス右下の「変更」ボタンを押した。 これでダウンロードとインストールが自動的に行われるので、しばらくの間待つ。 インストールが完了したが、「警告あり」と表示されてしまった。「問題の表示」によればMicrosoft.VisualStudio.AspNetDiagnosticPack.Msiのインストールに失敗したらしい。ここではこの問題には対処せず、無視して次の手順に進んだ。 Visual Studio Installerを終了
続きを読む